mosquitto_sub -h mqtt.tkkrlab.nl -t "test"

mosquitto_pub -h mqtt.tkkrlab.nl -t "test" -m "hello world"

#include <ESP8266WiFi.h>
#include <PubSubClient.h>

WiFiClient espClient;
PubSubClient client(espClient);

unsigned long previousMillis = 0;
const long interval = 1000;

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");
  for (int i=0;i<length;i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();
}

void setup() {
  Serial.begin(115200);
  
  WiFi.mode(WIFI_STA);
  WiFi.begin("ssid", "wachtwoord");
  WiFi.hostname("test-apparaat");
  
  client.setServer("mqtt.tkkrlab.nl", 1883);
  client.setCallback(callback);
}

void loop() {
  if (WiFi.status() != WL_CONNECTED) {
    //Niet verbonden met het netwerk...
    Serial.println("Wachten op WiFi...");
    delay(100);
  } else {
    //Verbonden met het netwerk.
    if (!client.connected()) {
      //Nog niet verbonden met de MQTT broker
      Serial.println(F("Wifi connected! Connecting to MQTT server..."));
      if (client.connect("uniekeNaamVoorDeClient")) {
        Serial.println("MQTT connected!");
        setInternalLed(true);
        client.subscribe("test");
      } else {
        Serial.print("failed, rc=");
        Serial.print(client.state());
        Serial.println(" (waiting 5 seconds before trying again...)");
        delay(5000);
      }
    } else {
      //Verbonden met de MQTT broker
      unsigned long currentMillis = millis();
      if (currentMillis - previousMillis >= interval) {
        previousMillis = currentMillis;
        client.publish("test", "hello world");
        client.publish("millis", String(currentMillis));
      }
    }
  }
}